Separated models, controllers and routers

OrderScreen/Controller.fs

@@ -0,0 +1,89 @@
+module DredgePos.OrderScreen.Controller
+
+open DredgePos
+open DredgeFramework
+open DredgePos.Types
+open Giraffe
+open Microsoft.AspNetCore.Http
+
+let getOrderScreenData (tableNumber: int) =
+    {|
+        order_screen_pages = Entity.GetAllInVenue<order_screen_page_group>
+        sales_categories = Entity.GetAllInVenue<sales_category>
+        print_groups = Entity.GetAllInVenue<print_group>
+        custom_item = Entity.GetAllByColumn<item> "item_code" "OPEN000" |> first
+        table = Floorplan.Model.getTable tableNumber
+    |}
+    |> ajaxSuccess
+    |> json
+
+let loadGrid (gridId: int) =
+    let grid = Entity.GetById<grid> gridId
+    let gridHtml = Model.loadGrid gridId
+    if gridHtml = "Error" then ajaxFail gridHtml
+    else ajaxSuccess {|grid=grid;gridHtml=gridHtml|}
+    |> json
+
+let loadOrderScreen (ctx: HttpContext)  (tableNumber: int) : HttpHandler =
+   Authenticate.Model.RequireClerkAuthentication ctx
+
+   let table = Floorplan.Model.getTable tableNumber
+
+   let covers = if tableNumber > 0 then table.default_covers else 0
+   let coverString = language.getAndReplace "covers" [covers]
+
+   let changeCoverNumberButton = if tableNumber > 0 then Theme.loadTemplateWithVars "orderScreen/change_cover_number_button" (map ["covers", coverString]) else ""
+
+   let orderNumber =
+       if tableNumber > 0 then language.getAndReplace "active_table" [tableNumber]
+       else language.get "new_order"
+
+   let containerAttributes =
+        if tableNumber > 0 then
+            map ["data-table", jsonEncode table]
+                |> Theme.htmlAttributes
+        else ""
+
+   let categoryList =
+       Entity.GetAllInVenue<order_screen_page_group>
+        |> Array.filter (fun page_group -> page_group.id <> 0)
+        |> Array.sortBy (fun {order=order} -> order)
+        |> Array.map (fun category ->
+            let categoryMap = recordToMap category
+            let categoryArray = map ["page", categoryMap]
+            Theme.loadTemplateWithArrays "orderScreen/page_group_button" categoryArray
+            )
+        |> joinWithNewLine
+
+   let grids =
+       Model.getAllPageGrids ()
+       |> Array.map Model.getPagesHTML
+       |> joinWithNewLine
+
+   let coverSelectorButtons =
+        Array.init (covers+1) id
+            |> Array.map(fun coverNumber ->
+                let text = if coverNumber > 0 then language.getAndReplace "selected_cover" [coverNumber]
+                           else language.get "cover_zero"
+                Theme.PosButton text "coverSelectorButton" $"""data-cover="{coverNumber}" """)
+            |> String.concat "\n"
+
+   let variables = map [
+       "title", "Order"
+       "containerAttributes", containerAttributes
+       "categoryList", categoryList
+       "pageGroups", grids
+       "orderNumber", orderNumber
+       "changeCoverNumberButton", changeCoverNumberButton
+       "covers", coverString
+       "salesCategoryOverrideButtons", Model.generateSalesCategoryOverrideButtons ()
+       "coverSelectorButtons", coverSelectorButtons
+   ]
+
+   let styles = ["dredgepos.orderScreen.css"]
+   let scripts = ["dredgepos.tables.js";"../external/currency.min.js";"dredgepos.orderScreen.js"; ]
+   let currentClerk = recordToMap <| Authenticate.Model.getCurrentClerk ctx
+   let arrays = map ["clerk", currentClerk]
+
+   Theme.loadTemplateWithVarsArraysScriptsAndStyles "orderScreen" variables arrays scripts styles
+    |> htmlString

OrderScreen/Model.fs

@@ -0,0 +1,136 @@
+module DredgePos.OrderScreen.Model
+
+open DredgeFramework
+open DredgePos
+open DredgePos.Types
+open FSharp.Collections
+open Thoth.Json.Net
+open Theme
+
+
+let getAllPageGrids () = Entity.GetAllInVenue<order_screen_page_group>
+                         |> Array.filter(fun pageGroup -> pageGroup.grid_id <> 0)
+                         |> Array.map(fun pageGroup -> (Entity.GetById<grid> pageGroup.grid_id), pageGroup)
+
+let getImageButtonData (button: button) =
+    let itemCode =
+        if button.primary_action = "item" then button.primary_action_value
+        else button.secondary_action_value
+
+    let item = Entity.GetAllByColumn<item> "item_code" itemCode
+                |> first
+
+    let extraData =
+        map [
+            "data-item", jsonEncode item
+        ] |> htmlAttributes
+
+    {|
+        extra_data = extraData
+        text = item.item_name
+    |}
+
+let getGridButtonData (button: button) =
+    let gridId =
+        if button.primary_action = "grid" then button.primary_action_value
+        else button.secondary_action_value
+        |> int
+
+    let grid = Entity.GetById<grid> gridId
+    {|
+        extra_data = map ["data-grid", jsonEncode gridId] |> htmlAttributes
+        text = grid.grid_name
+    |}
+
+let getActionData (button: button) (action: string) =
+    let actionValue =
+        if action = "primary" then button.primary_action
+        else button.secondary_action
+
+    match actionValue with
+        | "item" -> getImageButtonData button
+        | "grid" -> getGridButtonData button
+        | "spacer" ->  {|extra_data=""; text=""|}
+        | _ -> {|extra_data=""; text=""|}
+
+let renderButton (buttonId: int) =
+    let button = Entity.GetById<button> buttonId
+
+    let extra_styles =
+        match button.extra_styles.Length with
+            | 0 -> ""
+            | _ -> $""" style="{button.extra_styles}" """
+
+    let imageClass = if button.image.Length > 0 then "hasImage" else ""
+    let spacerClass = if button.primary_action = "spacer" || button.secondary_action = "spacer"
+                        then "invisible"
+                        else ""
+
+    let image = if button.image.Length > 0 then loadTemplateWithVars "orderScreen/button_image" (map ["image", button.image]) else ""
+
+    let extraClasses = [|imageClass; spacerClass|] |> String.concat " "
+
+    let primary_action_data = getActionData button "primary"
+    let secondary_action_data = getActionData button "secondary"
+
+    let action_extra_data = primary_action_data.extra_data + " " + secondary_action_data.extra_data
+    let button_text =
+        if button.text.Length > 0 then button.text
+        else
+            if primary_action_data.text.Length > 0 then primary_action_data.text
+            else secondary_action_data.text
+
+    let vars = map [
+        "extra_classes",  button.extra_classes + " " + extraClasses
+        "extra_styles", extra_styles
+        "primary_action", button.primary_action
+        "secondary_action", button.secondary_action
+        "text", button_text
+        "image", image
+        "extra_data", action_extra_data
+    ]
+
+    loadTemplateWithVars "orderScreen/grid_button" vars
+
+let renderPage (grid: grid)  (buttonHTML: string) =
+    let vars = map ["pageButtons", buttonHTML; "rows", string grid.grid_rows; "cols", string grid.grid_cols]
+    loadTemplateWithVars "orderScreen/page" vars
+
+let renderPageGroup (pageGroup: order_screen_page_group) (pageHTML: string) =
+    let vars = map [
+        "pages", pageHTML
+        "page_group_id", string pageGroup.id
+    ]
+    loadTemplateWithVars "orderScreen/page_group" vars
+
+let printGroupPosButton (printGroup: print_group) =
+    PosButton (language.getAndReplace "print_with" [printGroup.name]) "printGroupOverrideButton toggle" $"""data-value="{printGroup.id}" """
+
+let generateSalesCategoryOverrideButtons () =
+    Entity.GetAllInVenue<print_group>
+        |> Array.map printGroupPosButton
+        |> Array.append [|PosButton (language.getAndReplace "print_with" ["default"]) "printGroupOverrideButton toggle default active" """data-value="0" """|]
+        |> joinWithNewLine
+
+
+let renderGrid (grid: grid) =
+    let gridData = grid.grid_data |> Decode.Auto.fromString<Map<string, int[]>>
+
+    match gridData with
+        | Error _ -> "Error"
+        | Ok pages ->
+            pages
+                |> Map.toArray
+                |> Array.map snd
+                |> Array.map(fun row -> row |> Array.map renderButton |> String.concat "\n")
+                |> Array.map (renderPage grid)
+                |> joinWithNewLine
+
+let loadGrid gridId = renderGrid (Entity.GetById<grid> gridId)
+
+
+let getPagesHTML (gridInfo: grid * order_screen_page_group) =
+    let grid, pageGroup = gridInfo
+
+    renderGrid grid
+    |> renderPageGroup pageGroup

OrderScreen/Router.fs

@@ -0,0 +1,15 @@
+module DredgePos.OrderScreen.Router
+
+open DredgePos
+open DredgePos.Types
+open Saturn
+open Giraffe
+
+let router = router {
+    pipe_through Ajax.Router.pipeline
+    getf "/getOrderScreenData/%i" Controller.getOrderScreenData
+    getf "/getGridHtml/%i" Controller.loadGrid
+    post "/updateCovers" (bindJson<floorplan_table> (fun table -> Entity.Update table |> Array.head |> DredgeFramework.ajaxSuccess |> json))
+    get "/" (warbler (fun ctx -> Controller.loadOrderScreen (snd ctx) 0))
+    getf "/%i" (fun number -> (warbler (fun ctx -> Controller.loadOrderScreen (snd ctx) number)))
+}